View source for Manateelazycat 的 Emacs 启动文件 site-start.el 研究

Manateelazycat 的 Emacs 启动文件 [https://github.com/manateelazycat/lazycat-emacs/blob/master/site-start.el site-start.el] 写得很妙，值得研究。

== 源代码 ==
<syntaxhighlight lang="elisp">
(require 'cl-lib)

(tool-bar-mode -1)                      ;禁用工具栏
(menu-bar-mode -1)                      ;禁用菜单栏
(scroll-bar-mode -1)                    ;禁用滚动条

(defun add-subdirs-to-load-path (search-dir)
  (interactive)
  (let* ((dir (file-name-as-directory search-dir)))
    (dolist (subdir
             ;; 过滤出不必要的目录，提升Emacs启动速度
             (cl-remove-if
              #'(lambda (subdir)
                  (or
                   ;; 不是目录的文件都移除
                   (not (file-directory-p (concat dir subdir)))
                   ;; 父目录、 语言相关和版本控制目录都移除
                   (member subdir '("." ".." 
                                    "dist" "node_modules" "__pycache__" 
                                    "RCS" "CVS" "rcs" "cvs" ".git" ".github")))) 
              (directory-files dir)))
      (let ((subdir-path (concat dir (file-name-as-directory subdir))))
        ;; 目录下有 .el .so .dll 文件的路径才添加到 `load-path' 中，提升Emacs启动速度
        (when (cl-some #'(lambda (subdir-file)
                           (and (file-regular-p (concat subdir-path subdir-file))
                                ;; .so .dll 文件指非Elisp语言编写的Emacs动态库
                                (member (file-name-extension subdir-file) '("el" "so" "dll"))))
                       (directory-files subdir-path))

          ;; 注意：`add-to-list' 函数的第三个参数必须为 t ，表示加到列表末尾
          ;; 这样Emacs会从父目录到子目录的顺序搜索Elisp插件，顺序反过来会导致Emacs无法正常启动
          (add-to-list 'load-path subdir-path t))

        ;; 继续递归搜索子目录
        (add-subdirs-to-load-path subdir-path)))))

(add-subdirs-to-load-path "/usr/share/emacs/lazycat")

(require 'init)
</syntaxhighlight>

== 详细解析 ==
# (require 'cl-lib) 为要用到的 cl 做铺势
# -1 的三个选项很简单，不用谈
# 自定义了一个函数，叫 add-subdirs-to-load-path，它的变量是 search-dir
## interactive 意为可交互唤起，简单略
## let* 定义 dir
### 这里只定义了一个 dir，其实可以定义多个局部变量，* 是“多个”的意思
### 其实可以再加很多局部变量，如 ( (dir (one)) (zhangsan (two)) (lisi (three)) )，所以用了三层括号
### let* 把 dolist 包含在内，是划定 let 定义的变量的使用范围
## {{ftid|ft=dolist|id="tt-dolist"}}，对列表执行操作
### subdir 待处理的列表
#### cl-remove-if 列表里移除非目录、不相干目录
#### directory-files 把 dir 里的所有文件取出来
### 执行的操作是，在前提条件下，把 subdir-path 加入 load-path 列表末尾
#### 拼接 dir 和 subdir
#### cl-some 用 file-regular-p 过滤存有特定后缀文件的文件夹
# 运行 add-subdirs-to-load-path，"/usr/share/emacs/lazycat" 就是 search-dir

== 先验知识 ==
<span id="tt-dolist">dolist 的核心结构</span>：
<syntaxhighlight lang="elisp">
(dolist
(VAR LIST [RESULT])
BODY ...)
</syntaxhighlight>